Boyer-Moore byte array search

Private needle() As Byte = {&HE5, &H87, &H4A, &H3B, &H32, &H9B, &H61, &H40, &H84, &HC6, &HC3, &HB1, &HA7, &H30, &H4A, &H10}
 
    Private Function SimpleBoyerMooreSearch(ByVal haystack As Byte(), ByVal needle As Byte()) As Integer
        Dim lookup As Integer() = New Integer(255) {}
        For i As Integer = 0 To lookup.Length - 1
            lookup(i) = needle.Length
        Next
 
        For i As Integer = 0 To needle.Length - 1
            lookup(needle(i)) = needle.Length - i - 1
        Next
 
        Dim index As Integer = needle.Length - 1
        Dim lastByte As Byte = needle(needle.Length - 1)
        While index < haystack.Length
            Dim checkByte As Byte = haystack(index)
            If haystack(index) = lastByte Then
                Dim found As Boolean = True
                For j As Integer = needle.Length - 2 To 0 Step -1
                    If haystack(index - needle.Length + j + 1) <> needle(j) Then
                        found = False
                        Exit For
                    End If
                Next
 
                If found Then
                    Return index - needle.Length + 1
                Else
                    index += 1
                End If
            Else
                index += lookup(checkByte)
            End If
        End While
        Return -1
    End Function